Thunder and Lightning Effect Redux

				
					/*
  Nothing happens in a vacuum. Thanks to the following:

  DFPLayer documentation
  https://wiki.dfrobot.com/DFPlayer_Mini_SKU_DFR0299

  Indrek Luuk - Circuit Journal
  https://circuitjournal.com/how-to-use-the-dfplayer-mini-mp3-module-with-an-arduino

  One Guy, One Blog
  https://oneguyoneblog.com/2017/11/01/lightning-thunder-arduino-halloween-diy/

  "If I have seen further it is by standing on the shoulders of Giants."
  - Isaac Newton
*/

// these libraries must be installed prior to uploading
// includes
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

// assign pins to TX and RX for player
#define txPin 2
#define rxPin 3

// set up a new SoftwareSerial object
SoftwareSerial mySerial = SoftwareSerial(rxPin, txPin);

// create the player object
DFRobotDFPlayerMini myPlayer;

// set pin MOSFET is connected to
const int mosPin = 4;

// set high and low volume volume 0-31
const int volMin = 25;
const int volMax = 30;

// set total number of tracks - value should be one higher than total number
const int numTracks = 3;

// set the number of flashes in any given loop
const int flashCountMin = 10;
const int flashCountMax = 25;

// set flash duration range - ms
const int flashDurationMin = 25;
const int flashDurationMax = 150;

// set time to next flash range - ms
const int nextFlashDelayMin = 25;
const int nextFlashDelayMax = 75;

// set randomize pause between strikes
const int pauseBottom = 5000;
const int pauseTop = 10000;

void setup() {

  // set pin modes for TX and RX
  pinMode(rxPin, INPUT);
  pinMode(txPin, OUTPUT);

  // set the baud rate for the SoftwareSerial object
  mySerial.begin(9600);

  // connect to player
  if (myPlayer.begin(mySerial)) {
    Serial.println("Connection successful.");

    // set initial volume 0-30
    myPlayer.volume(0);

    // set equalizer
    // myPlayer.EQ(DFPLAYER_EQ_NORMAL);
    // myPlayer.EQ(DFPLAYER_EQ_POP);
    // myPlayer.EQ(DFPLAYER_EQ_ROCK);
    // myPlayer.EQ(DFPLAYER_EQ_JAZZ);
    myPlayer.EQ(DFPLAYER_EQ_CLASSIC);
    // myPlayer.EQ(DFPLAYER_EQ_BASS);
  } else {
    Serial.println("Connection failed.");
  }

  // set mosfet pin to output
  pinMode(mosPin, OUTPUT);
}

void loop() {

  // generate a random volume value to provide variety
  int randomVol = random(volMin, volMax);

  // select random track
  int randomTrack = random(1, numTracks);

  // lightning variables
  // number of flashes per cycle
  int flashCount = random(flashCountMin, flashCountMax);

  long strikeDelay = random(pauseBottom, pauseTop);

  // trigger audio - randomize volume and track
  myPlayer.volume(randomVol);
  myPlayer.play(randomTrack);

  // flash led while playing
  for (int flash = 0; flash <= flashCount; flash += 1) {
    digitalWrite(mosPin, HIGH);
    delay(random(flashDurationMin, flashDurationMax));
    digitalWrite(mosPin, LOW);
    delay(random(nextFlashDelayMin, nextFlashDelayMax));
  }

  // we'll use this variable to average out the value on the busy pin
  int busyPin = 0;

  // loop while busy pin reads low voltage
  while (busyPin < 300) {
    int i;
    int numReadings = 10;
    for (i = 0; i < numReadings; i++) {
      busyPin = busyPin + analogRead(A0);
      delay(1);
    }
    // average of all the readings.
    busyPin = busyPin / numReadings;
  }

  // random pause between strikes
  delay(strikeDelay);
}